Gradle: pasta resources visível no IDE
Publié le 16 August 2019
Em um projeto de aplicativo conduzido pelo gerenciador de compilação Gradle
é mais agradável ter visibilidade sobre todos os arquivos
participante do desenvolvimento da aplicação,
como pastas de recursos que não são
nos caminhos por convenção.
Por exemplo eu quero que a pasta src/jbake,
seja visível como ‘resource folder’,
é possível fazer isso entrando na configuração do projeto,
nos wizards da IDE No entanto esta opção não é salva no próximo recarregamento
do projeto Gradle na IDE. Para aplicar essa configuração permanentemente.
a solução é sobrescrever a configuração dos caminhos de fontes
no arquivo de configuração build.gradle tal como nas linhas 18, 19, 20 e 21 :
build.gradle
plugins {
id "java"
id "groovy"
id "org.jbake.site" version "5.0.0"
id "org.ajoberstar.git-publish" version "2.1.1"
}
repositories {
mavenCentral()
jcenter()
}
group project_group
version project_version
sourceSets {
main {
java { srcDirs = [] }
groovy { srcDirs =["src/main/java", "src/main/groovy"] }
resources {
srcDirs =[
"src/main/resources",
"src/jbake"//in order to get site src content in the IDE
]
}
}
test {
java { srcDirs = [] }
groovy { srcDirs =["src/test/java", "src/test/groovy"] }
}
}
test {
useJUnitPlatform()
}
configurations {
ivy
}
dependencies {
ivy "org.apache.ivy:ivy:$ivy_version"
implementation "org.codehaus.groovy:groovy-all:$groovy_version"
implementation "org.asciidoctor:asciidoctor-java-integration:$asciidoctor_java_integration_version"
implementation "org.freemarker:freemarker:$freemarker_version"
testImplementation "org.junit.jupiter:junit-jupiter-api:$junit5_version"
testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junit5_version"
}
gitPublish {
repoUri = github_pages_blog_repository
branch = git_branch
contents {
from(file(jbake_content_from)) {
into jbake_content_to
}
}
}
tasks.withType(GroovyCompile) {
groovyClasspath += configurations.ivy
}